#!/bin/zsh -e
source common.zsh
VERSION=(3 4.0 4.1 4.2)
PROTO=(tcp)

zparseopts -D -K \
	c:=CLIENT -client:=CLIENT \
	k:=SCRATCH -scratch:=SCRATCH \
	-nconnect:=NCONNECT \
	p:=MOUNTPOINT -mountpoint:=MOUNTPOINT \
	q:=SCRATCHMNT -scratchmnt:=SCRATCHMNT \
	r:=RDMA -rdma:=RDMA \
	s:=SERVER -server:=SERVER \
	x:=EXPORT -export:=EXPORT \
	v+:=VERSION -version+:=VERSION

COLOR=$BIN/colors/xfstests.py
OPTIONS="sec=sys"
RESULT_BASE=$HOME/.local/share/xfstests/
DATE=$(date +%Y-%m-%d-%H:%M:%S%z)
TODAY=$(date +%Y/%m/%d)
NOW=$(date +%H:%M:%S%z)
REMOTE_RESULTS=xfstests-dev/results/
RESULTS=$RESULT_BASE/date/$TODAY/${SERVER[-1]}/
TMP_RESULTS=/tmp/xfstests/${SERVER[-1]}/$NOW
TAG=$(kernel-tag.zsh ${CLIENT[-1]})
if [ ! -z $TAG ]; then
	TAGRES=$RESULT_BASE/tags/$TAG/${SERVER[-1]}
fi

#
# Prepare to test
#
function setup_client_func()
{
	client_setup xfstests.zsh ${SERVER[-1]} ${EXPORT[-1]} \
				  ${MOUNTPOINT[-1]} ${SCRATCH[-1]} \
				  ${SCRATCHMNT[-1]} $USER
}
prepare_to_test
if [ ${#NCONNECT} -gt 0 ]; then
	OPTIONS="$OPTIONS,nconnect=${NCONNECT[-1]}"
fi

testargs=()
for arg in $*; do
	testargs+=($(printf '%q' "$arg"))
done

run_xfs_tests() {
	client_run xfstests.zsh --server ${SERVER[-1]} \
				--export ${EXPORT[-1]} \
				--mountpoint ${MOUNTPOINT[-1]} \
				--scratch ${SCRATCH[-1]} \
				--scratchmnt ${SCRATCHMNT[-1]} \
				--proto $1 \
				--version $2 \
				--opts $OPTIONS \
				--user $USER $testargs | python $COLOR $1 $2
	scp -q ${CLIENT[-1]}:$REMOTE_RESULTS/$1/$2/result.xml $TMP_RESULTS/$1-$2.xml
}

#
# Run tests
#
mkdir -p $TMP_RESULTS
for proto in $PROTO; do
	for vers in $VERSION; do
		case $vers in
			"-v" | "--version") continue ;;
		esac

		run_xfs_tests $proto $vers &
	done
done

wait

mkdir -p $RESULTS
tar -cJf $RESULTS/$NOW.tar.xz -C $(dirname $TMP_RESULTS) $NOW/
if [ ! -z "$TAG" ]; then
	mkdir -p $TAGRES
	ln $RESULTS/$NOW.tar.xz $TAGRES/$DATE.tar.xz
fi
report-xfstests.py $RESULTS/$NOW.tar.xz & disown