ocarina/tests/core/Sconscript

#!/usr/bin/python
import os
Import("env", "UnitTest", "testing_group")

res = []
core_objs = []

def CoreTest(name, source):
	global core_objs

	test = os.path.abspath(source)
	core = os.path.sep.join([x for x in test.split("/") if x != "tests"])
	if os.path.exists(core):
		core_objs += [ env.Object(core) ]
	run = UnitTest("core/%s" % name, [ test ] + core_objs)
	Alias("tests/core", run)
	if len(res) > 0 and testing_group(["tests/core"]):
		Depends(run, res[-1])
	return run
Export("core_objs", "CoreTest")


res += [ CoreTest("version",  "version.c")    ]
res += [ CoreTest("string",   "string.c")     ]
res += [ CoreTest("random",   "random.c")     ]
res += [ CoreTest("file",     "file.c")       ]
res += [ CoreTest("date",     "date.c")       ]

res += SConscript("containers/Sconscript")
res += [ CoreTest("filter",   "filter.c")     ]
res += [ CoreTest("idle",     "idle.c")       ]

res += SConscript("tags/Sconscript")
res += [ CoreTest("queue",    "queue.c")      ]
res += [ CoreTest("playlist", "playlist.c")   ]
res += [ CoreTest("collection", "collection.c") ]
res += [ CoreTest("deck",     "deck.cpp")     ]
res += [ CoreTest("audio",    "audio.cpp")    ]

Return("res")