#!/usr/bin/python
import os
Import("env", "UnitTest", "testing_group")

res = []
core_objs = []

def CoreTest(name, source):
	global core_objs
	if os.path.exists("../../core/%s" % source):
		core_objs += [ env.Object("../../core/%s" % source) ]
	run = UnitTest("core/%s" % name, [ source ] + core_objs)
	Alias("tests/core", run)
	if len(res) > 0 and testing_group(["tests/core"]):
		Depends(run, res[-1])
	return run
Export("core_objs")


res += [ CoreTest("version",  "version.c")    ]
res += [ CoreTest("string",   "string.c")     ]
res += [ CoreTest("random",   "random.c")     ]
res += [ CoreTest("file",     "file.c")       ]
res += [ CoreTest("date",     "date.c")       ]

tmp = SConscript("containers/Sconscript")
if testing_group(["tests/core"]):
	Depends(tmp[0], res[-1])
res += tmp

res += [ CoreTest("filter",   "filter.c")     ]
res += [ CoreTest("idle",     "idle.c")       ]

tmp = SConscript("tags/Sconscript")
if testing_group(["tests/core"]):
	Depends(tmp[0], res[-1])
res += tmp

res += [ CoreTest("queue",    "queue.c")      ]
res += [ CoreTest("playlist", "playlist.c")   ]
res += [ CoreTest("collection", "collection.c") ]
res += [ CoreTest("deck",     "deck.cpp")     ]
res += [ CoreTest("audio",    "audio.cpp")    ]

Return("res")