#!/bin/zsh -e
source common.zsh
TESTS=(-a)

zparseopts -F -K \
	a+=TESTS -all+=TESTS \
	b+=TESTS -basic+=TESTS \
	c:=CLIENT -client:=CLIENT \
	-dmesg=DMESG -srvdmesg=SRVDMESG \
	g+=TESTS -general+=TESTS \
	l+=TESTS -locking+=TESTS \
	p:=MOUNTPOINT -mountpoint:=MOUNTPOINT \
	-nconnect:=NCONNECT \
	-krb5=KRB5 \
	r:=RDMA -rdma:=RDMA \
	-rwsize:=RWSIZE \
	S+=TESTS -special+=TESTS \
	s:=SERVER -server:=SERVER \
	x:=EXPORT -export:=EXPORT \
	v+:=VERSION -version+:=VERSION

COLOR=$BIN/colors/cthon.py
SEC=(sys)
ARGS=()

prepare_to_test

if [[ ${TESTS[(ie)-a]} -le ${#TESTS} ]]; then
	TESTS=(-b -g -s -l)
fi
if [ ${#RDMA} -gt 0 ]; then
	ARGS+=("--rdma")
fi
if [ ${#NCONNECT} -gt 0 ]; then
	ARGS+=("--mntopt nconnect=${NCONNECT[-1]}")
fi
if [ ${#RWSIZE} -gt 0 ]; then
	ARGS+=("--mntopt rsize=${RWSIZE[-1]}")
	ARGS+=("--mntopt wsize=${RWSIZE[-1]}")
fi
if [ ${#KRB5} -gt 0 ]; then
	SEC+=(krb5 krb5i krb5p)
fi

for vers in $VERSION; do
	ARGS+=("--version $vers")
done

ret=0
set +e
date | python -u $COLOR
for test in $TESTS; do
	for sec in $SEC; do
		client_run cthon.zsh --server ${SERVER[-1]} \
				     --export ${EXPORT[-1]} \
				     --mountpoint ${MOUNTPOINT[-1]} \
				     --user $USER --mntopt sec=$sec \
				       $test $ARGS | python -u $COLOR
		ret=$((ret+$?))
	done
done

exit $ret